Das offizielle Minecraft Wiki twittert hier: Wiki-Twitter  –  Chatte im Wiki-Discord  – Noch keinen Server gefunden? Es gibt einen Wiki-Server
Aktuell: Hilf mit, das Technik Wiki auf 1.13 zu bringen => HIER

Anlagen/Käfigzone (Befehle)

Aus Technik Wiki
Wechseln zu: Navigation, Suche
Gruppe: Grid Klebriger Kolben.png
Anlagen

Grid Roter Sand blass.png mit Mechaniken

Grid Redstone blass.png mit Redstone
                Hier:
Grid Befehlsblock.png mit Befehlen

Die vorgestellte Technik kann in der Redstone-Welt angesehen werden.

Die Käfigzone ist eine Anlage, die dafür sorgt, das bestimmte Spieler oder andere Objekte nicht den eingestellten Ort verlassen können. Hierbei können unterschiedliche Kriterien dafür vorgegeben sein, so kann ein bestimmter verbotener Gegenstand dazu führen, das man in so eine Käfigzone gelangt oder wenn man eine unerwünschte Handlung eingeleitet hat, wie beispielsweise das Töten von Dorfbewohnern. Es kann aber auch aus ganz anderen Umstände nötig sein eine Käfigzone einzurichten, so kann man, wenn beispielsweise Dorfbewohner nicht abhauen sollen, welche gerne weitläufige Areale erkunden, davon gestoppt werden, in dem man sie in eine dieser Bereiche steckt.

Variante 1[Bearbeiten | Quelltext bearbeiten]

Anlagen Käfigzone (Befehle) Animation 1.1.1.png Anlagen Käfigzone (Befehle) Animation 1.1.2.png

Diese Käfigzone hält den Dorfbewohner davon ab einen bestimmten Bereich zu verlassen, jedoch kann er immer noch sich frei innerhalb eines bestimmten Radius bewegen. Um die Käfigzone einzurichten, wird ein Rüstungsständer erstelltBefehl 1.1, welcher klein ist und eine Barriere im Kopfslot trägt. Nun wird an seiner Position ein Dorfbewohner erzeugt, welcher keine Angebote besitztBefehl 1.2. Dieser wird je nach belieben zufällig irgendwo hin laufen wollen, wenn er das versucht, wird nun erfasst, ob er sich zu weit vom Rüstungsständer bewegt, wenn das der Fall ist, erhält er zuerst einen Effekt, damit er langsamer herumlaufen kannBefehl 1.3 und anschließend wird er wieder zum Rüstungsständer mit dem Barrierenkopf teleportiertBefehl 1.4. Der Dorfbewohner kann den Ort nicht verlassen und wird immer zum Ausgangspunkt teleportiert. Wenn man die Käfigzone ausschaltet, so werden der Dorfbewohner und der Rüstungsständer gelöschtBefehl 1.5, dabei tragen beide das gleiche Etikett, welches die unterschiedlichen Objekte beide erfasst.


Befehlsblöcke mit Befehlen:
summon minecraft:armor_stand ~10 ~-1 ~ {CustomName:"ObjKäfigZ:1Zone",Small:true,Marker:true,Tags:["EtiKäfigZ:1Alle"],ArmorItems:[{},{},{},{id:"minecraft:barrier",Count:1b} ] }
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:1Zone] ~ ~ ~ /summon minecraft:villager ~ ~ ~ {Tags:["EtiKäfigZ:1Alle"],Offers:{Recipes:[] } }


execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:1Zone] ~ ~ ~ /effect @e[type=minecraft:villager,rm=1,r=2] minecraft:slowness 1 5 true
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:1Zone] ~ ~ ~ /teleport @e[type=minecraft:villager,rm=1,r=2] ~ ~ ~


kill @e[tag=EtiKäfigZ:1Alle]

Variante 2[Bearbeiten | Quelltext bearbeiten]

Anlagen Käfigzone (Befehle) Bild 2.1.png Anlagen Käfigzone (Befehle) Bild 2.2.png

Mit dieser Käfigzone ist es möglich Spieler, die einen selbst festgelegten verbotenen Gegenstand besitzen, in einer Käfigzone festzuhalten, bis sie den Gegenstand aus ihrem Inventar droppen. Dazu wird beim Einschalten ein Drop erzeugt, welcher der besagte verbotene Gegenstand darstelltBefehl 2.1. In diesem Beispiel ist es eine Barriere, welche einmal in der Welt mit einer sichtbaren Schrift anzeigt, das dieser Drop verboten ist und zum anderen zeigt er auch im Inventar an, was mit diesem Gegenstand besonders ist. Im Anschluss wird ein kleiner Rüstungsständer erzeugtBefehl 2.2, welcher eine Barriere im Kopfslot trägt und damit anzeigt, das sich um ihm herum die Käfigzone befindet. Damit man nun erfassen kann ob sich der verbotene Gegenstand im Inventar des Spielers befindet, wird ihm ein Etikett verpasst, welches dann anzeigt, das er den Gegenstand besitzt, dazu muss aber zuerst dieses Etikett entfernt werdenBefehl 2.3, bevor es dann erneut wieder gegeben werden kann, wenn er den Gegenstand noch besitztBefehl 2.4. Damit der Spieler bescheid weiss, das er den Gegenstand nicht behalten darf, wird ihm direkt im Anschluss eine Nachricht übermitteltBefehl 2.5. Er bekommt zusätzlich auch den Effekt AbbaulähmungBefehl 2.6 und VerlangsamungBefehl 2.7. Erst jetzt wird er zur Käfigzone teleportiertBefehl 2.8. Wenn er sich nun in der Käfigzone befindet, kann der Spieler sich dort in einem Radius von zwei Metern frei bewegen. Er wird aber sofort wieder in die Mitte teleportiert, falls er versucht sich weiter davon zu entfernen. Beim Ausschalten der Anlage, wird der eventuell gedroppte Gegenstand mit einem Etikett markiertBefehl 2.9 um anschließend dieses und auch den Rüstungsständer zu löschenBefehl 2.10, welcher ebenfalls das gleiche Etikett besitzt. Als letztes wird das Inventar des Spielers von der Barriere bereinigtBefehl 2.11


Befehlsblöcke mit Befehlen:
summon minecraft:item ~5 ~-1 ~ {Item:{id:"minecraft:barrier",Count:1b,tag:{display:{Name:"Käfigzone:2",Lore:["Dieser Gegenstand ist verboten!"] } } },CustomName:"Verboten!",CustomNameVisible:true,Tags:["EtiKäfigZ:2Alle"] }
summon minecraft:armor_stand ~10 ~-2 ~ {CustomName:"ObjKäfigZ:2Zone",Small:true,Tags:["EtiKäfigZ:2Alle"],ArmorItems:[{},{},{},{id:"minecraft:barrier",Count:1b} ] }


scoreboard players tag @a[tag=EtiKäfigZ:2VerbotenerGegenstand] remove EtiKäfigZ:2VerbotenerGegenstand
scoreboard players tag @a[tag=!EtiKäfigZ:2VerbotenerGegenstand] add EtiKäfigZ:2VerbotenerGegenstand {Inventory:[{id:"minecraft:barrier",tag:{display:{Name:"Käfigzone:2"} } } ] }
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:2Zone] ~ ~ ~ /tellraw @a[tag=EtiKäfigZ:2VerbotenerGegenstand,rm=2] ["Käfigzone:2 ",{"text":"Du besitzt einen verbotenen Gegenstand, wirf ihn mit Q weg!","color":"red","bold":"true"} ]
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:2Zone] ~ ~ ~ /effect @a[tag=EtiKäfigZ:2VerbotenerGegenstand,rm=2] minecraft:mining_fatigue 1 5 true
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:2Zone] ~ ~ ~ /effect @a[tag=EtiKäfigZ:2VerbotenerGegenstand,rm=2] minecraft:slowness 1 5 true
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:2Zone] ~ ~ ~ /teleport @a[tag=EtiKäfigZ:2VerbotenerGegenstand,rm=2] ~ ~ ~


scoreboard players tag @e[type=minecraft:item] add EtiKäfigZ:2Alle {Item:{tag:{display:{Name:"Käfigzone:2"} } } }
kill @e[tag=EtiKäfigZ:2Alle,r=50]
clear @a[r=25] minecraft:barrier -1 9999 {display:{Name:"Käfigzone:2"} }

Variante 3[Bearbeiten | Quelltext bearbeiten]

Anlagen Käfigzone (Befehle) Bild 3.1.png Anlagen Käfigzone (Befehle) Bild 3.2.png

Diese Käfigzone sperrt Spieler für eine bestimmte Zeit ein, welche andere Kreaturen beispielsweise Dorfbewohner töten. Dazu wird ein Punktestand-Ziel erstellt, welches alle Morde des Spielers aufzähltBefehl 3.1. Dann wird ein kleiner Rüstungsständer erzeugt, welcher die Käfigzone repräsentiertBefehl 3.3. Nun werden mehrere Dorfbewohner erzeugtBefehl 3.3. Diese reiten alle auf einem Drop, welcher durch sein Alter sofort verschwindet, dadurch sind die Dorfbewohner nicht mehr am reiten und können nun durch den /spreadplayers-Befehl um die Käfigzone verteilt werdenBefehl 3.4. Als letztes Bekommt der Spieler ein Diamantschwert, mit dem er nun die Dorfbewohner schaden zufügen kannBefehl 3.5. Wird nun ein Dorfbewohner getötet, so wird automatisch sein Punktestand um eins erhöht. Das wiederum wird nun abgefragt und der Spieler erhält zuerst eine NachrichtBefehl 3.6. Dann wird sein Punktestand auf minus zweihundert gesetztBefehl 3.7, damit nun eine Zeit laufen kann. Alle Spieler die nun unter null einen Punktestand haben werden in die Käfigzone teleportiertBefehl 3.8. Damit die Spieler wissen, wie lang sie dort gefangen sind, erhalten sie eine Nachricht über der Schnellzugriffsleiste, welche die aktuellen verbliebenen Ticks anzeigtBefehl 3.9. Als letztes wird der Punktestand für die Zeit um eins erhöht für jeden SpielerBefehl 3.10. Der Spieler kann nun zusehen wie die Ticks immer weniger werden, jedoch kann er nicht vor null aus der Käfigzone ausbrechen, dann wird er immer wieder zu dieser teleportiert. Nach Ablauf der Zeit kann der Spieler wieder frei herumlaufen als ob nichts geschehen wäre. Wird die Käfigzone ausgeschaltet, wird das Punktestand-Ziel gelöschtBefehl 3.11, das eventuell gedroppte Schwert mit einem Etikett ausgestattetBefehl 3.12 damit dann alle Objekte, wie Rüstungsständer, Dorfbewohner und Schwert gelöscht werden könnenBefehl 3.13. Als letztes wird dem Spieler das Schwert, wenn er es nicht gedroppt hat aus dem Inventar gelöschtBefehl 3.14.


Befehlsblöcke mit Befehlen:
scoreboard objectives add PZKäfigZ:3Tote totalKillCount
summon minecraft:armor_stand ~5 ~-2 ~ {CustomName:"ObjKäfigZ:3Zone",Small:true,Marker:true,Tags:["EtiKäfigZ:3Alle"],ArmorItems:[{},{},{},{id:"minecraft:barrier",Count:1b} ] }
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:3Zone] ~ ~ ~ /summon minecraft:item ~ ~ ~ {Item:{id:"minecraft:barrier",Count:1b},Age:6000,Tags:["EtiKäfigZ:3Alle"],Passengers:[{id:"minecraft:villager",Tags:["EtiKäfigZ:3Alle"],Offers:{Recipes:[] } },{id:"minecraft:villager",Tags:["EtiKäfigZ:3Alle"],Offers:{Recipes:[] } },{id:"minecraft:villager",Tags:["EtiKäfigZ:3Alle"],Offers:{Recipes:[] } } ] }
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:3Zone] ~ ~ ~ /spreadplayers ~ ~ 0 5 false @e[type=minecraft:villager,tag=EtiKäfigZ:3Alle]
give @a[r=25] minecraft:diamond_sword 1 0 {display:{Name:"Käfigzone:3",Lore:["Töte mit dem Schwert","die Dorfbewohner um","deine Strafe zu erhalten"] } }


execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:3Zone] ~ ~ ~ /tellraw @a[score_PZKäfigZ:3Tote_min=1,score_PZKäfigZ:3Tote=1] ["Käfigzone:3 ",{"text":"Du hast unerlaubt einen Dorfbewohner getötet! Dafür musst du büßen!","color":"red","bold":"true"} ]
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:3Zone] ~ ~ ~ /scoreboard players set @a[score_PZKäfigZ:3Tote_min=1,score_PZKäfigZ:3Tote=1] PZKäfigZ:3Tote -200
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:3Zone] ~ ~ ~ /teleport @a[score_PZKäfigZ:3Tote=-1,rm=2] ~ ~ ~
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:3Zone] ~ ~ ~ /execute @a[score_PZKäfigZ:3Tote=1,r=2] ~ ~ ~ /title @p actionbar ["",{"text":"Freiheit in ","color":"red"},{"score":{"name":"@p","objective":"PZKäfigZ:3Tote"} } ]
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:3Zone] ~ ~ ~ /scoreboard players add @a[score_PZKäfigZ:3Tote=-1] PZKäfigZ:3Tote 1


scoreboard objectives remove PZKäfigZ:3Tote
scoreboard players tag @e[type=minecraft:item] add EtiKäfigZ:3Alle {Item:{tag:{display:{Name:"Käfigzone:3"} } } }
kill @e[tag=EtiKäfigZ:3Alle]
clear @a[r=25] minecraft:diamond_sword -1 9999 {display:{Name:"Käfigzone:3"} }

Variante 4[Bearbeiten | Quelltext bearbeiten]

Anlagen Käfigzone (Befehle) Bild 4.1.png Anlagen Käfigzone (Befehle) Bild 4.2.png

Diese Käfigzonen sind so programmiert, das wenn sich freie Spieler in die Zone begeben, sie für eine bestimmte Zeit dort gefangen sind, bevor sie die Zone wieder verlassen können. Wird nun die Anlage eingeschaltet, so wird zuerst ein Punktestand-Ziel erstelltBefehl 4.1, welches die Zeit der Gefangenschaft des Spielers zählt. Danach werden drei Käfigzonen erstellt, in dem drei Rüstungsständer auf einem Drop reitend erstellt werdenBefehl 4.2. Durch das Reiten auf einem Drop, welcher augenblicklich nach der Erstellung wieder verschwindet, sind die Rüstungsständer frei und agieren so, als ob sie einzeln per Befehl erstellt wurden. Nun können sie großflächig verteilt werdenBefehl 4.3. die Rüstungsständer, welche als Käfigzone arbeiten, besitzen eine Barriere gut sichtbar im Kopfslot und besitzen keine Hitbox (Marker). Nun geht es weiter mit dem aktiven Wiederhol-Befehlsblock. Damit Spieler die die Käfigzone betreten haben nur für eine bestimmte Zeit dort gefangen sind, wird zuerst von diesen Spielern aus, die noch nicht gefangen sind eine Zeit auf den Rüstungsständer übertragenBefehl 4.4. Dieser Zeitwert wird pro Spieler auf den Rüstungsständer drauf addiert, das bedeutet, wenn mehrere Spieler der Zone zu nah gekommen, sind müssen alle zusammen länger warten, bis sie frei gelassen werden. Anschließend erhalten die Spieler eine Nachricht, damit sie wissen, was los istBefehl 4.5. Nun bekommen sie alle eine Etikett und sind damit markiert für die GefangenschaftBefehl 4.6. Damit man nun auch prüfen kann, ob sich gefangene Spieler auf der Flucht von dieser Käfigzone machen, wird nun ein zweites Etikett allen Gefangenen gegebenBefehl 4.7, welches nur die erhalten, die sich auch innerhalb des Käfigs aufhalten. Alle Gefangenen die sich außerhalb des Käfigs aufhalten, bekommen das Etikett nichtBefehl 4.7. Dadurch kann nun unterschieden welcher Gefangene wieder zurück in die Käfigzone teleportiert werden mussBefehl 4.8. Zusätzlich kann über dieses zweite Etikett auch die Gefangenen ausmachen, die ihre Zeit abgesessen haben und nun in die Freiheit entlassen werden können. Dazu erhalten sie zuerst eine NachrichtBefehl 4.9, ehe sie dann das erste Etikett, welches sie als Gefangener markiert, entfernt bekommenBefehl 4.10. Gefangene werden erst nach Ablaufen der Zeit frei gelassen, dies wird festgestellt, in dem geschaut wird ob der Rüstungsständer einen Wert von null besitzt. Das zweite Etikett, welches benutzt wird um Flüchtige zu erfassen muss nun wieder entfernt werden, damit man beim nächsten Durchlauf wieder die Spieler erfassen kann, die flüchten wollenBefehl 4.11. Damit die Gefangenen auch sehen können, wie lange sie gefangen gehalten werden, wird ihnen über der Schnellzugriffsleiste die Zeit eingeblendetBefehl 4.12. Jeden Durchlauf, wird dann der Zeitwert bei den Rüstungsständern um eins verringert, bis er null erreichtBefehl 4.13. Um das Quader um die Käfigzonen herum sichtbar zu machen, werden Flammen-Partikel in einem Viereck um diese Zonen angeordnetBefehl 4.14Befehl 4.15Befehl 4.16Befehl 4.17. Wird die Anlage ausgeschaltet, so wird das Punktestand-Ziel gelöschtBefehl 4.18, alle Zonen ebenfallsBefehl 4.19 und die Etikette, die der Spieler eventuell noch besitzt, werden entferntBefehl 4.20Befehl 4.21.


Befehlsblöcke mit Befehlen:
scoreboard objectives add PZKäfigZ:4Zeit dummy
summon minecraft:item ~ ~10 ~ {Item:{id:"minecraft:barrier",Count:1b},Age:6000,Tags:["EtiKäfigZ:4Alle"],Passengers:[{id:"minecraft:armor_stand",CustomName:"ObjKäfigZ:4Zone",Small:true,Marker:true,Tags:["EtiKäfigZ:4Alle"],ArmorItems:[{},{},{},{id:"minecraft:barrier",Count:1b} ] },{id:"minecraft:armor_stand",CustomName:"ObjKäfigZ:4Zone",Small:true,Marker:true,Tags:["EtiKäfigZ:4Alle"],ArmorItems:[{},{},{},{id:"minecraft:barrier",Count:1b} ] },{id:"minecraft:armor_stand",CustomName:"ObjKäfigZ:4Zone",Small:true,Marker:true,Tags:["EtiKäfigZ:4Alle"],ArmorItems:[{},{},{},{id:"minecraft:barrier",Count:1b} ] } ] }
execute @e[type=minecraft:item,tag=EtiKäfigZ:4Alle] ~ ~ ~ /spreadplayers ~ ~ 24 25 false @e[type=minecraft:armor_stand,tag=EtiKäfigZ:4Alle]


execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:4Zone] ~-5 ~ ~-5 /execute @a[x=~,y=~,z=~,dx=10,dy=10,dz=10,tag=!EtiKäfigZ:4Gefangen] ~ ~ ~ /scoreboard players add @e[type=minecraft:armor_stand,name=ObjKäfigZ:4Zone,c=1] PZKäfigZ:4Zeit 200
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:4Zone] ~-5 ~ ~-5 /tellraw @a[x=~,y=~,z=~,dx=10,dy=10,dz=10,tag=!EtiKäfigZ:4Gefangen] ["Käfigzone:4 ",{"text":"Du hast dich der Zone zu stark genähert, dafür wirst du nun hier verweilen müssen!","color":"red","bold":"true"} ]
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:4Zone] ~-5 ~ ~-5 /scoreboard players tag @a[x=~,y=~,z=~,dx=10,dy=10,dz=10,tag=!EtiKäfigZ:4Gefangen] add EtiKäfigZ:4Gefangen
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:4Zone] ~-5 ~ ~-5 /scoreboard players tag @a[x=~,y=~,z=~,dx=10,dy=10,dz=10,tag=!EtiKäfigZ:4ImKäfig] add EtiKäfigZ:4ImKäfig
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:4Zone,score_PZKäfigZ:4Zeit_min=1] ~ ~ ~ /execute @a[tag=EtiKäfigZ:4Gefangen] ~ ~ ~ /tp @p[tag=!EtiKäfigZ:4ImKäfig,r=0] @e[type=minecraft:armor_stand,name=ObjKäfigZ:4Zone,score_PZKäfigZ:4Zeit_min=1,c=1]
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:4Zone,score_PZKäfigZ:4Zeit=0] ~ ~ ~ /execute @a[tag=!EtiKäfigZ:4ImKäfig,rm=5,r=10] ~ ~ ~ /tellraw @p[tag=EtiKäfigZ:4Gefangen,r=0] ["Käfigzone:4 ",{"text":"Du bist nun frei, verlasse diese Zone!","color":"red","bold":"true"} ]
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:4Zone,score_PZKäfigZ:4Zeit=0] ~ ~ ~ /execute @a[tag=!EtiKäfigZ:4ImKäfig,rm=5,r=10] ~ ~ ~ /scoreboard players tag @p[tag=EtiKäfigZ:4Gefangen,r=0] remove EtiKäfigZ:4Gefangen
scoreboard players tag @a[tag=EtiKäfigZ:4ImKäfig] remove EtiKäfigZ:4ImKäfig
execute @e[type=minecraft:armor_stand,name=ObjKäfigZ:4Zone,score_PZKäfigZ:4Zeit_min=0] ~-5 ~ ~-5 /title @a[x=~,y=~,z=~,dx=10,dy=10,dz=10,tag=EtiKäfigZ:4Gefangen] actionbar ["",{"text":"Freiheit in ","color":"red"},{"score":{"name":"@e[type=minecraft:armor_stand,name=ObjKäfigZ:4Zone,score_PZKäfigZ:4Zeit_min=0,c=1]","objective":"PZKäfigZ:4Zeit"} } ]
scoreboard players remove @e[type=minecraft:armor_stand,name=ObjKäfigZ:4Zone,score_PZKäfigZ:4Zeit_min=0] PZKäfigZ:4Zeit 1
execute @e[type=armor_stand,name=ObjKäfigZ:4Zone] ~-5 ~ ~-5 /particle flame ~ ~0.1 ~5 0 0 2 0.01 5 force @a[r=25]
execute @e[type=armor_stand,name=ObjKäfigZ:4Zone] ~-5 ~ ~-5 /particle flame ~5 ~0.1 ~ 2 0 0 0.01 5 force @a[r=25]
execute @e[type=armor_stand,name=ObjKäfigZ:4Zone] ~-5 ~ ~-5 /particle flame ~5 ~0.1 ~10 2 0 0 0.01 5 force @a[r=25]
execute @e[type=armor_stand,name=ObjKäfigZ:4Zone] ~-5 ~ ~-5 /particle flame ~10 ~0.1 ~5 0 0 2 0.01 5 force @a[r=25]


scoreboard objectives remove PZKäfigZ:4Zeit
kill @e[type=minecraft:armor_stand,tag=EtiKäfigZ:4Alle]
scoreboard players tag @a[tag=EtiKäfigZ:4Gefangen] remove EtiKäfigZ:4Gefangen
scoreboard players tag @a[tag=EtiKäfigZ:4ImKaäfig] remove EtiKäfigZ:4ImKäfig


Disambig color.svg
Promotional Content