Das offizielle Minecraft Wiki twittert hier: Wiki-Twitter     Noch keinen Server gefunden? Es gibt einen Wiki-Server
Nicht die Technik gefunden, die du suchst? Dann schlag sie vor: Gemeinschaftsportal

Anlagen/Zonen-Markierung (Befehle)

Aus Technik Wiki
Wechseln zu: Navigation, Suche
Gruppe: Grid Klebriger Kolben.png
Anlagen

Grid Roter Sand blass.png mit Mechaniken

Grid Redstone blass.png mit Redstone
                Hier:
Grid Befehlsblock.png mit Befehlen

Diese Technik ist noch in
keiner Download-Welt enthalten.
Disambig color.svg
Roter Sand.png
Alle Techniken auf dieser Seite sind noch nicht in der aktuellen Mechanik-Welt vorhanden.
In einem der nächsten Updates werden sie dort hinzugefügt werden.

Die Zonen-Markierung gibt einem die Möglichkeit eine Zone leicht zu erkennen. Dazu gibt sie sobald man sie betritt einen Benachrichtigung oder sie ist durch bestimmte Markierungen für den Spieler visuell sichtbar. Die Zonen können dabei kugelförmig aber auch kubusförmig sein.

Variante 1[Bearbeiten | Quelltext bearbeiten]

Anlagen Zonen-Markierung (Befehle) Bild 1.1.png Anlagen Zonen-Markierung (Befehle) Bild 1.2.png

Mit dieser Anlage kann eine runde kugelförmige Zone markiert werden. Dazu stellt man in ihr Zentrum einen Rüstungsständer auf[B1.1]. Nun wird ein Wiederhol-Befehlsblock benötigt, der die Benachrichtigung erledigt[B1.2]. Damit der Spieler der die Zone betritt nur einmal eine Nachricht nach dem Betreten bekommt, wird zuvor geprüft ob er ein Etikett besitzt, wenn nicht, so bekommt er die Nachricht. Direkt im Anschluss bekommen alle Spieler die kein Etikett haben und sich innerhalb der Zone aufhalten ein Etikett[B1.3]. Falls man die Zone wieder verlässt wird einem auch das Etikett wieder entfernt, damit man beim nächsten erneuten Betreten auch wieder eine Nachricht erhält[B1.4]. Damit die Zone auch von der Umgebung her, etwas sichtbar ist, werden Partikel kreisförmig um den Rüstungsständer erzeugt[B1.5]. Wird die Anlage ausgeschaltet, so wird der erschaffene Rüstungsständer wieder gelöscht[B1.6] und das eventuell noch angeheftete Etikett vom Spieler entfernt[B1.7].


Befehlsblöcke mit Befehlen:
/summon minecraft:armor_stand ~-5 ~-1 ~ {CustomName:"ObjZonMa:1Zone",Small:true,Marker:true,Tags:["EtiZonMa:1Alle"],ArmorItems:[{},{},{},{id:"minecraft:chest",Count:1b} ] }


/execute @e[type=minecraft:armor_stand,name=ObjZonMa:1Zone] ~ ~ ~ /tellraw @a[tag=!EtiZonMa:1Nachricht,r=5] ["",{"text":"Zonen-Markierung:1 "},{"text":"Willkommen in Blockhausen"} ]
/execute @e[type=minecraft:armor_stand,name=ObjZonMa:1Zone] ~ ~ ~ /scoreboard players tag @a[tag=!EtiZonMa:1Nachricht,r=5] add EtiZonMa:1Nachricht
/execute @e[type=minecraft:armor_stand,name=ObjZonMa:1Zone] ~ ~ ~ /scoreboard players tag @a[tag=EtiZonMa:1Nachricht,rm=6,r=10] remove EtiZonMa:1Nachricht
/execute @e[type=minecraft:armor_stand,name=ObjZonMa:1Zone] ~ ~ ~ /particle happyVillager ~ ~0.1 ~ 2 0 2 0.01 1 force @a[r=25]


/kill @e[tag=EtiZonMa:1Alle]
/scoreboard players tag @a[tag=EtiZonMa:1Nachricht] remove EtiZonMa:1Nachricht

Variante 2[Bearbeiten | Quelltext bearbeiten]

Anlagen Zonen-Markierung (Befehle) Bild 2.1.png Anlagen Zonen-Markierung (Befehle) Bild 2.2.png Anlagen Zonen-Markierung (Befehle) Bild 2.3.png Anlagen Zonen-Markierung (Befehle) Bild 2.4.png

Diese Anlage erkennt ob sich der Spieler zum ersten mal auf der Zone aufhält und gibt dann eine Titel-Nachricht aus. Dazu wird wieder ein Rüstungsständer wie in der vorigen Variante als Zone benutzt[B2.1]. Nun wird ein Wiederhol-Befehlsblock benutzt um die Titel-Nachricht einmal auszusenden[B2.2]. Diese wird nur dann dem Spieler gezeigt, wenn er noch nicht das Etikett bekommen hat und somit noch nie auf der Zone war[B2.3]. Nun wird im Chat eine Nachricht ausgegeben das er die Zone gerade betreten hat[B2.4], wenn er noch nicht dazu ein Etikett bekommen hat[B2.5]. Wenn der Spieler dann sich entschließt die Zone wieder zu verlassen, so erhält er auch dann wieder eine Nachricht, welche ihm mitteilt, das er so eben die Zone verlassen hat[B2.6]. Im Anschluss bekommt er auch das Etikett, welches für diese Nachrichten benutzt wird, wieder entfernt[B2.7]. Damit auch hier wieder die Zone etwas sichtbarer ist, wird ein Partikel-Effekt um den Rüstungsständer herum aktiv[B2.8]. Wenn man die Anlage wieder ausschaltet, so wird der Rüstungsständer, der die Zone repräsentiert wieder gelöscht[B2.9] und die beiden Etiketten, die die Spieler eventuell noch besitzen entfernt[B2.10][B2.11].


Befehlsblöcke mit Befehlen:
/summon minecraft:armor_stand ~-5 ~-1 ~ {CustomName:"ObjZonMa:2Zone",Small:true,Marker:true,Tags:["EtiZonMa:2Alle"],ArmorItems:[{},{},{},{id:"minecraft:chest",Count:1b} ] }


/execute @e[type=minecraft:armor_stand,name=ObjZonMa:2Zone] ~ ~ ~ /title @a[tag=!EtiZonMa:2Erstbetritt,r=5] title ["",{"text":"[ Blockhausen ]"} ]
/execute @e[type=minecraft:armor_stand,name=ObjZonMa:2Zone] ~ ~ ~ /scoreboard players tag @a[tag=!EtiZonMa:2Erstbetritt,r=5] add EtiZonMa:2Erstbetritt
/execute @e[type=minecraft:armor_stand,name=ObjZonMa:2Zone] ~ ~ ~ /tellraw @a[tag=!EtiZonMa:2Nachricht,r=5] ["",{"text":"Zonen-Markierung:2 "},{"text":"Du betrittst Blockhausen"} ]
/execute @e[type=minecraft:armor_stand,name=ObjZonMa:2Zone] ~ ~ ~ /scoreboard players tag @a[tag=!EtiZonMa:2Nachricht,r=5] add EtiZonMa:2Nachricht
/execute @e[type=minecraft:armor_stand,name=ObjZonMa:2Zone] ~ ~ ~ /tellraw @a[tag=EtiZonMa:2Nachricht,rm=6,r=10] ["",{"text":"Zonen-Markierung:2 "},{"text":"Du verlässt Blockhausen"} ]
/execute @e[type=minecraft:armor_stand,name=ObjZonMa:2Zone] ~ ~ ~ /scoreboard players tag @a[tag=EtiZonMa:2Nachricht,rm=6,r=10] remove EtiZonMa:2Nachricht
/execute @e[type=minecraft:armor_stand,name=ObjZonMa:2Zone] ~ ~ ~ /particle happyVillager ~ ~0.1 ~ 2 0 2 0.01 1 force @a[r=25]


/kill @e[tag=EtiZonMa:2Alle]
/scoreboard players tag @a[tag=EtiZonMa:2Nachricht] remove EtiZonMa:2Nachricht
/scoreboard players tag @a[tag=EtiZonMa:2Erstbetritt] remove EtiZonMa:2Erstbetritt

Variante 3[Bearbeiten | Quelltext bearbeiten]

Anlagen Zonen-Markierung (Befehle) Bild 3.1.png Anlagen Zonen-Markierung (Befehle) Bild 3.2.png Anlagen Zonen-Markierung (Befehle) Bild 3.3.png Anlagen Zonen-Markierung (Befehle) Bild 3.4.png

Mit dieser Zonen-Markierung lassen sich rechteckige Zone abstecken und für alle Spieler sichtbar machen. Wenn man dann die Welt beendet und erneut beitritt wird, auch die Zone nochmals eingeblendet, in der man sich gerade befindet. Dazu wird zuerst ein Punktestand-Ziel benötigt[B3.1], welches das Verlassen der Welt erkennen kann. Nun werden zwei Zonen in Form von Rüstungsständer erstellt[B3.2][B3.3], welche dann um sich jeweils eine Steinstufen-Abgrenzung platzieren lassen[B3.4][B3.5]. Dazu werden in einem Quadrat um die Rüstungsständer Steinstufen überall gesetzt wo sich Luft befindet und anschließend der Innenbereich wieder frei geräumt, damit nur die Zonen-Abgrenzung übrig bleibt. Darauf folgt ein Wiederhol-Befehlsblock der nun versucht ein eventuell vorhandenes Etikett vom Spieler auf Zone eins zu entfernen, wenn er die Welt neu betreten hat[B3.6], dies wird ebenfalls bei der zweiten Zone versucht[B3.7]. Dabei wird geschaut ob sich der Spieler in einem Kubus innerhalb der Zone aufhält und bekommt dann das Etikett entfernt. Wenn der Spieler der Welt beigetreten ist, ist sein Punktestand auf eins, welcher jetzt permanent auslösen würde, deshalb muss nun der Punktestand zurückgesetzt werden[B3.8]. Nachfolgend wird nun geprüft ob der Spieler genau diese Etiketten nicht besitzt und bekommt, wenn das zutrifft eine Titel-Nachricht, zur jeweiligen Zone[B3.9][B3.11]. Nach der Titel-Nachricht wird ihm für die jeweilige Zone ein Etikett gegeben, welches die Titel-Nachricht von nun an verhindert[B3.10][B3.12]. Abgesehen von der Titel-Nachricht soll der Spieler aber jedes mal wenn er die Zone betritt eine Chat-Nachricht erhalten, dazu wird getestet, ob der Spieler ein Etikett besitzt das aussagt, das er bereits die Chat-Nachricht erhalten hat, wenn er es noch nicht besitzt und nun in die Zone gelangt ist, bekommt er die Nachricht[B3.13] um im gleichen Moment auch das Etikett zu bekommen[B3.14]. Um nun festzustellen ob der Spieler die Zone verlassen hat, muss man etwas fingierter vorgehen, dort reicht es nicht aus, einen Kubus um die Zone herum abzufragen, um so den Spieler zu erfassen der die Zone verlassen hat. Stattdessen wird abgefragt ob Spieler, die auf der Zone sind ein Etikett besitzen das aussagt, das sie bei der Zone sind[B3.15]. Wenn nun Spieler die die Chat-Nachricht erhalten haben außerhalb der Zone sind, besitzen sie nicht das so erwähnte Etikett und können nun erfasst werden. Sie erhalten eine Chat-Nachricht, das sie die Zone verlassen haben[B3.16] und bekommen dann auch das Etikett entfernt, das für das Blockieren der Chat-Nachricht erforderlich war[B3.17]. Nun bekommen alle Spieler das Etikett entfernt, das für die Bestimmung der Spieler die außerhalb der Zone sind entfernt[B3.18]. Damit ist die Zonen-Markierung grundsätzlich fertig, allerdings soll sie auch noch durch Partikel eine Art Barriere bilden, die nur dann zu sehen ist, wenn die Spieler außerhalb der Zone sind. Dazu werden Partikel um die Zone herum erzeugt[B3.19][B3.20][B3.21][B3.22]. Wenn man nun eine Zone betritt erhält man eine Chat-Nachricht und beim erstmaligen Betreten zusätzlich auch eine Titel-Nachricht. Verlässt man dann die Welt und betritt sie erneut, so wird die Titel-Nachricht erneut abgespielt. Verlässt man die Zone erhält man eine Chat-Nachricht die einem ansagt, welche Zone man verlassen hat. Möchte man die Anlage ausschalten, so legt man den Hebel wieder in Ausgangsstellung um und dadurch werden dann das Punktestand-Ziel[B3.23], die Zonen[B3.24][B3.25] und die Etiketten[B3.26][B3.27][B3.28][B3.29] entfernt.


Befehlsblöcke mit Befehlen:
/scoreboard objectives add PZZonMa:3Betritt stat.leaveGame
/summon minecraft:armor_stand ~-20 ~-2 ~10 {CustomName:"Befehlehausen",CustomNameVisible:true,Small:true,Marker:true,Tags:["EtiZonMa:3Alle"],ArmorItems:[{},{},{},{id:"minecraft:command_block",Count:1b} ] }
/summon minecraft:armor_stand ~-20 ~-3 ~-10 {CustomName:"Mechanikhausen",CustomNameVisible:true,Small:true,Marker:true,Tags:["EtiZonMa:3Alle"],ArmorItems:[{},{},{},{id:"minecraft:sand",Count:1b,Damage:1f} ] }
/execute @e[type=minecraft:armor_stand,tag=EtiZonMa:3Alle] ~-7 ~ ~-7 /fill ~ ~ ~ ~15 ~ ~15 minecraft:stone_slab 0 replace minecraft:air
/execute @e[type=minecraft:armor_stand,tag=EtiZonMa:3Alle] ~-7 ~ ~-7 /fill ~1 ~ ~1 ~14 ~ ~14 minecraft:air 0 replace minecraft:stone_slab


/execute @e[type=minecraft:armor_stand,name=Befehlehausen] ~-7 ~ ~-7 /scoreboard players tag @a[x=~,y=~,z=~,dx=15,dy=15,dz=15,tag=EtiZonMa:3ErstbetrittBefehlehausen,score_PZZonMa:3Betritt_min=1] remove EtiZonMa:3ErstbetrittBefehlehausen
/execute @e[type=minecraft:armor_stand,name=Mechanikhausen] ~-7 ~ ~-7 /scoreboard players tag @a[x=~,y=~,z=~,dx=15,dy=15,dz=15,tag=EtiZonMa:3ErstbetrittMechanikhausen,score_PZZonMa:3Betritt_min=1] remove EtiZonMa:3ErstbetrittMechanikhausen
/scoreboard players set @a[score_PZZonMa:3Betritt_min=1] PZZonMa:3Betritt 0
/execute @e[type=minecraft:armor_stand,name=Befehlehausen] ~-7 ~ ~-7 /title @a[x=~,y=~,z=~,dx=15,dy=15,dz=15,tag=!EtiZonMa:3ErstbetrittBefehlehausen] title ["",{"text":"[ "},{"selector":"@e[type=minecraft:armor_stand,tag=EtiZonMa:3Alle,c=1]"},{"text":" ]"} ]
/execute @e[type=minecraft:armor_stand,name=Befehlehausen] ~-7 ~ ~-7 /scoreboard players tag @a[x=~,y=~,z=~,dx=15,dy=15,dz=15,tag=!EtiZonMa:3ErstbetrittBefehlehausen] add EtiZonMa:3ErstbetrittBefehlehausen
/execute @e[type=minecraft:armor_stand,name=Mechanikhausen] ~-7 ~ ~-7 /title @a[x=~,y=~,z=~,dx=15,dy=15,dz=15,tag=!EtiZonMa:3ErstbetrittMechanikhausen] title ["",{"text":"[ "},{"selector":"@e[type=minecraft:armor_stand,tag=EtiZonMa:3Alle,c=1]"},{"text":" ]"} ]
/execute @e[type=minecraft:armor_stand,name=Mechanikhausen] ~-7 ~ ~-7 /scoreboard players tag @a[x=~,y=~,z=~,dx=15,dy=15,dz=15,tag=!EtiZonMa:3ErstbetrittMechanikhausen] add EtiZonMa:3ErstbetrittMechanikhausen
/execute @e[type=minecraft:armor_stand,tag=EtiZonMa:3Alle] ~-7 ~ ~-7 /tellraw @a[x=~,y=~,z=~,dx=15,dy=15,dz=15,tag=!EtiZonMa:3Nachricht] ["",{"text":"Zonen-Markierung:3 "},{"text":"Du betrittst "},{"selector":"@e[type=minecraft:armor_stand,tag=EtiZonMa:3Alle,c=1]"} ]
/execute @e[type=minecraft:armor_stand,tag=EtiZonMa:3Alle] ~-7 ~ ~-7 /scoreboard players tag @a[x=~,y=~,z=~,dx=15,dy=15,dz=15,tag=!EtiZonMa:3Nachricht] add EtiZonMa:3Nachricht
/execute @e[type=minecraft:armor_stand,tag=EtiZonMa:3Alle] ~-7 ~ ~-7 /scoreboard players tag @a[x=~,y=~,z=~,dx=15,dy=15,dz=15,tag=!EtiZonMa:3BeiZone] add EtiZonMa:3BeiZone
/execute @a[tag=EtiZonMa:3Nachricht] ~ ~ ~ /execute @p[tag=!EtiZonMa:3BeiZone,r=0] ~ ~ ~ /execute @e[type=minecraft:armor_stand,tag=EtiZonMa:3Alle,c=1] ~ ~ ~ /execute @a[tag=EtiZonMa:3Nachricht] ~ ~ ~ /tellraw @p[tag=!EtiZonMa:3BeiZone,r=0] ["",{"text":"Zonen-Markierung:3 "},{"text":"Du verlässt "},{"selector":"@e[type=minecraft:armor_stand,tag=EtiZonMa:3Alle,c=1]"} ]
/execute @a[tag=EtiZonMa:3Nachricht] ~ ~ ~ /scoreboard players tag @p[tag=!EtiZonMa:3BeiZone,r=0] remove EtiZonMa:3Nachricht
/scoreboard players tag @a[tag=EtiZonMa:3BeiZone] remove EtiZonMa:3BeiZone
/execute @a[tag=!EtiZonMa:3Nachricht] ~ ~ ~ /execute @e[type=minecraft:armor_stand,tag=EtiZonMa:3Alle,r=50] ~ ~ ~8 /particle totem ~ ~2 ~ 3 0 0 0.2 5 force @a[r=25]
/execute @a[tag=!EtiZonMa:3Nachricht] ~ ~ ~ /execute @e[type=minecraft:armor_stand,tag=EtiZonMa:3Alle,r=50] ~ ~ ~-7 /particle totem ~ ~2 ~ 3 0 0 0.2 5 force @a[r=25]
/execute @a[tag=!EtiZonMa:3Nachricht] ~ ~ ~ /execute @e[type=minecraft:armor_stand,tag=EtiZonMa:3Alle,r=50] ~8 ~ ~ /particle totem ~ ~2 ~ 0 0 3 0.2 5 force @a[r=25]
/execute @a[tag=!EtiZonMa:3Nachricht] ~ ~ ~ /execute @e[type=minecraft:armor_stand,tag=EtiZonMa:3Alle,r=50] ~-7 ~ ~ /particle totem ~ ~2 ~ 0 0 3 0.2 5 force @a[r=25]


/scoreboard objectives remove PZZonMa:3Betritt
/execute @e[type=minecraft:armor_stand,tag=EtiZonMa:3Alle] ~-7 ~ ~-7 /fill ~ ~ ~ ~15 ~ ~15 minecraft:air 0 replace minecraft:stone_slab 0
/kill @e[tag=EtiZonMa:3Alle]
/scoreboard players tag @a[tag=EtiZonMa:3Nachricht] remove EtiZonMa:3Nachricht
/scoreboard players tag @a[tag=EtiZonMa:3ErstbetrittBefehlehausen] remove EtiZonMa:3ErstbetrittBefehlehausen
/scoreboard players tag @a[tag=EtiZonMa:3ErstbetrittMechanikhausen] remove EtiZonMa:3ErstbetrittMechanikhausen
/scoreboard players tag @a[tag=EtiZonMa:3BeiZone] remove EtiZonMa:3BeiZone