Das offizielle Minecraft Wiki twittert hier: Wiki-Twitter  –  Chatte im Wiki-Discord  – Noch keinen Server gefunden? Es gibt einen Wiki-Server
Das Technik Wiki besitzt nun eine brasilianisch-portugiesische Übersetzung.

Vorrichtungen/Drop-Sensor (Befehle)

Aus Technik Wiki
Wechseln zu: Navigation, Suche
Gruppe: Grid Kolben.png
Vorrichtungen

Grid Roter Sand blass.png mit Mechaniken

Grid Redstone blass.png mit Redstone
                Hier:
Grid Befehlsblock.png mit Befehlen

Die vorgestellte Technik kann in der Redstone-Welt angesehen werden.

Ein Drop-Sensor kann wie der Name schon sagt, erkennen ob bestimmte Drops in der Welt herumliegen, ob man aus seinem Inventar Gegenstände gedroppt hat oder aufgehoben hat. Gegenstände kann man dabei mit Q droppen, wodurch dieser Sensor auch als Q-Tasten-Sensor benutzt werden kann, je nach Spielereinstellung.

Variante 1[Bearbeiten | Quelltext bearbeiten]

Vorrichtungen Drop-Sensor (Befehle) Bild 1.1.png Vorrichtungen Drop-Sensor (Befehle) Bild 1.2.png

Mit dem Drop-Sensor kann man erfassen ob man allgemein irgendeinen Gegenstand gedroppt hat. Hierzu wird eine Statistik aufgerufen, welche in das Punktestand-Ziel gespeichert wird, wenn man den Hebel umlegtBefehl 1.1. Im Anschluss erhält man 64 DiamantenBefehl 1.2. Sobald man einen Gegenstand droppt, wird die Statistik bei sich um eins erhöht, was dann der Wiederhol-Befehlsblock jeden Tick abfragt. Wenn man einen Gegenstand gedroppt hat, erhält man zuerst eine NachrichtBefehl 1.3. Danach wird der gedroppte Gegenstand gelöschtBefehl 1.4. Weil man beim Droppen den Gegenstand in Bauchhöhe von sich wirft, wird vom Spieler aus in dieser Höhe der eine Gegenstand in einem Radius von einem Meter gesucht und anschließend entfernt. Danach wird der Punktestand des Spielers wieder zurück gesetzt, damit man jeden weiteren Wurf aus dem Inventar erneut erfassen kannBefehl 1.5. Legt man den Hebel wieder um, so wird auf der anderen Seite vom Befehlsblock eine Redstone-Fackel aktiviert, welche Befehlsblöcke aktiviert. Dadurch wird das Punktestand-Ziel gelöschtBefehl 1.6 und die noch eventuell vorhandenen Gegenstände aus dem Inventar des Spielers gelöschtBefehl 1.7.


Befehlsblöcke mit Befehlen:
scoreboard objectives add PZDrSen:1 stat.drop
give @a[r=25] minecraft:diamond 64 0 {display:{Name:"Drop-Sensor:1",Lore:["Wirf den Gegenstand mit Q"] } }


tellraw @a[score_PZDrSen:1_min=1] ["Drop-Sensor:1 ",{"text":"Du hast einen Gegenstand gedroppt"} ]
execute @a[score_PZDrSen:1_min=1] ~ ~1 ~ /kill @e[type=minecraft:item,c=1,r=1]
scoreboard players reset @a[score_PZDrSen:1_min=1] PZDrSen:1


scoreboard objectives remove PZDrSen:1
clear @a[r=25] minecraft:diamond -1 9999 {display:{Name:"Drop-Sensor:1"} }

Variante 2[Bearbeiten | Quelltext bearbeiten]

Vorrichtungen Drop-Sensor (Befehle) Bild 2.1.png Vorrichtungen Drop-Sensor (Befehle) Bild 2.2.png

Mit diesem Drop-Sensor kann man spezielle Gegenstände die gedroppt wurden abfragen. Hierbei werden zwei Punktestand-Ziele benötigt, die jeweils die Statistik für die beiden Gegenstände speichernBefehl 2.1Befehl 2.2. Im Anschluss bekommt der Spieler Gold- und Eisenbarren ins InventarBefehl 2.3. Hierbei werden die Gegenstände als Drop übereinander an der Position des Spielers gespawnt. Nun wird zuerst geprüft ob der Spieler Goldbarren gedroppt hat, wenn das geschehen ist, wird dem Spieler der Punktestand um eins automatisch erhöht und kann nun abgefragt werden. Dazu bekommt der Spieler eine NachrichtBefehl 2.4 und der Gegenstand wird in seiner Bauchhöhe gelöschtBefehl 2.5. Als letztes wird der Punktestand zurückgesetztBefehl 2.6. Das gleiche läuft nun auch für die Eisenbarren ab. Zuerst bekommt der Spieler eine NachrichtBefehl 2.7 und dann wird der Gegenstand gelöschtBefehl 2.8. Anschließend wird auch hier der Punktestand zurückgesetztBefehl 2.9, damit man erneut abfragen kann ob der Gegenstand geworfen wurde. Schaltet man die Vorrichtung aus, so werden die beiden Punktestand-Ziele gelöschtBefehl 2.10Befehl 2.11 und die beiden Gegenstandsstapel aus dem Inventar entferntBefehl 2.12Befehl 2.13.


Befehlsblöcke mit Befehlen:
scoreboard objectives add PZDrSen:2Au stat.drop.minecraft.gold_ingot
scoreboard objectives add PZDrSen:2Fe stat.drop.minecraft.iron_ingot
execute @a[r=25] ~ ~ ~ /summon minecraft:item ~ ~ ~ {Item:{id:"minecraft:gold_ingot",Count:64b,tag:{display:{Name:"Drop-Sensor:2",Lore:["Wirf den Gegenstand mit Q"] } } },Passengers:[{id:"minecraft:item",Item:{id:"minecraft:iron_ingot",Count:64b,tag:{display:{Name:"Drop-Sensor:2",Lore:["Wirf den Gegenstand mit Q"] } } } } ] }


tellraw @a[score_PZDrSen:2Au_min=1] ["Drop-Sensor:2 ",{"text":"Du hast Goldbarren gedroppt"} ]
execute @a[score_PZDrSen:2Au_min=1] ~ ~1 ~ /kill @e[type=minecraft:item,c=1,r=1]
scoreboard players reset @a[score_PZDrSen:2Au_min=1] PZDrSen:2Au
tellraw @a[score_PZDrSen:2Fe_min=1] ["Drop-Sensor:2 ",{"text":"Du hast Eisenbarren gedroppt"} ]
execute @a[score_PZDrSen:2Fe_min=1] ~ ~1 ~ /kill @e[type=minecraft:item,c=1,r=1]
scoreboard players reset @a[score_PZDrSen:2Fe_min=1] PZDrSen:2Fe


scoreboard objectives remove PZDrSen:2Au
scoreboard objectives remove PZDrSen:2Fe
clear @a[r=25] minecraft:gold_ingot -1 9999 {display:{Name:"Drop-Sensor:2"} }
clear @a[r=25] minecraft:iron_ingot -1 9999 {display:{Name:"Drop-Sensor:2"} }

Variante 3[Bearbeiten | Quelltext bearbeiten]

Vorrichtungen Drop-Sensor (Befehle) Bild 3.1.png Vorrichtungen Drop-Sensor (Befehle) Bild 3.2.png

Mit diesem Drop-Sensor werden Drops in der Welt erfasst und bekommen dann einen Namen, der für alle sichtbar ist. Dazu wird ein Gegenstand als Drop gespawntBefehl 3.1, welcher noch einen sichtbaren Namen bekommen wird und der Spieler erhält einen Stapel vom selben GegenstandstypBefehl 3.2. Nun wird geprüft ob die Gegenstände, die als Drop in der Welt herumliegen den Anforderungen entsprechen. Dazu wird geprüft ob sie den entsprechenden Namen besitzenBefehl 3.3. Wenn das der Fall ist, bekommen sie ein Etikett, welches genau solche Drops markiert. Nun erhalten genau solche Drops, die das entsprechende Etikett aufweisen einen sichtbaren NamenBefehl 3.4. Damit sie nur einmal bearbeitet werden, wegen dem Namen, bekommen sie nun noch ein zweites Etikett, welches diese Drops für eine erneute Sichtbarmachung des Namens außen vor hältBefehl 3.5. Wenn man nun die Vorrichtung wieder ausschaltet, werden alle herumliegenden Drops gelöschtBefehl 3.6 und alle verbliebenen Gegenstände im Inventar gelöschtBefehl 3.7.


Befehlsblöcke mit Befehlen:
summon minecraft:item ~ ~ ~-2 {Item:{id:"minecraft:torch",Count:1b,tag:{display:{Name:"Drop-Sensor:3",Lore:["Wirf den Gegenstand mit Q"] } } } }
give @a[r=25] minecraft:torch 64 0 {display:{Name:"Drop-Sensor:3",Lore:["Wirf den Gegenstand mit Q"] } }


scoreboard players tag @e[type=minecraft:item,tag=!EtiDrSen:3Drop,r=25] add EtiDrSen:3Drop {Item:{tag:{display:{Name:"Drop-Sensor:3"} } } }
execute @e[type=minecraft:item,tag=EtiDrSen:3Drop,r=25] ~ ~ ~ /entitydata @e[type=minecraft:item,tag=!EtiDrSen:3DropName,r=25] {CustomName:"Drop",CustomNameVisible:true}
scoreboard players tag @e[type=minecraft:item,tag=!EtiDrSen:3DropName,r=25] add EtiDrSen:3DropName {CustomName:"Drop",CustomNameVisible:true}


kill @e[type=minecraft:item,tag=EtiDrSen:3Drop]
clear @a[r=25] minecraft:torch -1 9999 {display:{Name:"Drop-Sensor:3"} }

Variante 4[Bearbeiten | Quelltext bearbeiten]

Vorrichtungen Drop-Sensor (Befehle) Bild 4.1.png Vorrichtungen Drop-Sensor (Befehle) Bild 4.2.png

Mit diesem Drop-Sensor lassen sich mehrere Drops in der Welt unterscheiden und Ereignisse auslösen, wenn eine bestimmte Kombination der Drops auftritt. Dazu wird ein Punktestand-Ziel benötigtBefehl 4.1, welches die Nummer der Drops speichern kann. Anschließend müssen dem Spieler alle Gegenstände gegeben werden, welche er droppen können sollBefehl 4.2Befehl 4.3Befehl 4.4. Jeder gedroppte Gegenstand wird geprüft und wenn es sich dabei um einen der drei zu prüfenden Gegenstände handelt, erhält er eine NummerBefehl 4.5Befehl 4.6Befehl 4.7. Damit sie nur einmal die Nummer erhalten wird nun noch dafür gesorgt, das sie ein Etikett bekommenBefehl 4.8, welches weitere Überprüfungen dieser Drops verhindert. Damit nun der Drop, der einen Ofen darstellt auch heißt, wird an seiner Position mehrere Flammenpartikel erzeugtBefehl 4.9. Wenn sich nun im Radius von drei Metern um diesem Ofen-Drop mit der Nummer eins Drops aufhalten, die eine höhere Nummer besitzen, entstehen Rauchpartikel, so als ob der Ofen sie nun erhitzen würdeBefehl 4.10. Somit erfasst der Ofen alle voreingestellten Drops und könnte noch weitere Dinge daraufhin anstellen. In diesem Beispiel bleibt es jedoch dabei. Wenn man die Vorrichtung wieder ausschaltet, wird das Punktestand-Ziel gelöschtBefehl 4.11, die in der Welt herumliegenden Drops entferntBefehl 4.12 und die drei Stapel aus dem Inventar entferntBefehl 4.13Befehl 4.14Befehl 4.15.


Befehlsblöcke mit Befehlen:
scoreboard objectives add PZDrSen:4Nr dummy
give @a[r=25] minecraft:stick 64 0 {display:{Name:"Drop-Sensor:4",Lore:["Wirf den Gegenstand mit Q"] } }
give @a[r=25] minecraft:coal 64 0 {display:{Name:"Drop-Sensor:4",Lore:["Wirf den Gegenstand mit Q"] } }
give @a[r=25] minecraft:furnace 64 0 {display:{Name:"Drop-Sensor:4",Lore:["Wirf den Gegenstand mit Q"] } }


scoreboard players set @e[type=minecraft:item,tag=!EtiDrSen:4Drop,r=25] PZDrSen:4Nr 1 {Item:{id:"minecraft:furnace",tag:{display:{Name:"Drop-Sensor:4"} } } }
scoreboard players set @e[type=minecraft:item,tag=!EtiDrSen:4Drop,r=25] PZDrSen:4Nr 2 {Item:{id:"minecraft:coal",tag:{display:{Name:"Drop-Sensor:4"} } } }
scoreboard players set @e[type=minecraft:item,tag=!EtiDrSen:4Drop,r=25] PZDrSen:4Nr 3 {Item:{id:"minecraft:stick",tag:{display:{Name:"Drop-Sensor:4"} } } }
scoreboard players tag @e[type=minecraft:item,tag=!EtiDrSen:4Drop,score_PZDrSen:4Nr_min=1,r=25] add EtiDrSen:4Drop {Item:{tag:{display:{Name:"Drop-Sensor:4"} } } }
execute @e[type=minecraft:item,tag=EtiDrSen:4Drop,score_PZDrSen:4Nr_min=1,score_PZDrSen:4Nr=1,r=25] ~ ~ ~ /particle flame ~ ~ ~ 0 0 0 0.02 5 @a[r=25]
execute @e[type=minecraft:item,tag=EtiDrSen:4Drop,score_PZDrSen:4Nr_min=1,score_PZDrSen:4Nr=1,r=25] ~ ~ ~ /execute @e[type=minecraft:item,tag=EtiDrSen:4Drop,score_PZDrSen:4Nr_min=2,r=3] ~ ~ ~ /particle cloud ~ ~ ~ 0 0 0 0.02 1 @a[r=25]


scoreboard objectives remove PZDrSen:4Nr
kill @e[type=minecraft:item,tag=EtiDrSen:4Drop]
clear @a[r=25] minecraft:stick -1 9999 {display:{Name:"Drop-Sensor:4"} }
clear @a[r=25] minecraft:coal -1 9999 {display:{Name:"Drop-Sensor:4"} }
clear @a[r=25] minecraft:furnace -1 9999 {display:{Name:"Drop-Sensor:4"} }

Variante 5[Bearbeiten | Quelltext bearbeiten]

Vorrichtungen Drop-Sensor (Befehle) Bild 5.1.png Vorrichtungen Drop-Sensor (Befehle) Bild 5.2.png

Dieser Drop-Sensor kann erkennen ob der Spieler bestimmte Drops aufgehoben hat. Dazu wird beim Umlegen des Hebels ein Punktestand-Ziel mit einer Statistik erstelltBefehl 5.1, welches das Aufheben von roten Shulkerkisten erkennen kann. Danach wird ein fallender Block erstellt, welcher keine weiteren NBT-Daten besitzt und dadurch sofort wieder verschwindet, erzeugt, welcher auf sich zwei Drops beherbergt, welche der eigentliche Zweck des ganzen sindBefehl 5.2. Denn nun hat mehrere Drops auf einmal und ohne Passagierbindung können sie nun einfach auf eine bestimmte Fläche verteilt werdenBefehl 5.3. Wenn nun der Spieler zu diesen Drops läuft und sie versucht aufzuheben, so wird der Drop ins Inventar des Spieler geholt und er bekommt eine NachrichtBefehl 5.4. Danach wird sein Inventar von diesem einen Gegenstand befreitBefehl 5.5 und der Punktestand, der automatisch hochzählt, wenn Drops aufsammelt wird wieder zurückgesetztBefehl 5.6. Alle Gegenstände die man in diesem Beispiel aufsammelt werden nach dem Aufsammeln wieder gelöscht, man kann es aber auch anders lösen. Wenn man nun den Hebel wieder umlegt, so wird dafür gesorgt, dass das Punktestand-Ziel gelöscht wirdBefehl 5.7 und alle noch vorhandenen Drops ebenfallsBefehl 5.8.


Befehlsblöcke mit Befehlen:
scoreboard objectives add PZDrSen:5Aufheb stat.pickup.minecraft.red_shulker_box
summon minecraft:falling_block ~ ~ ~-2 {Block:"minecraft:barrier",Tags:["EtiDrSen:5Alle"],Passengers:[{id:"minecraft:item",Tags:["EtiDrSen:5Alle"],CustomName:"Hol mich",CustomNameVisible:true,Item:{id:"minecraft:red_shulker_box",Count:1b,tag:{display:{Name:"Drop-Sensor:5",Lore:["Hebe den Gegenstand auf"] } } } },{id:"minecraft:item",Tags:["EtiDrSen:5Alle"],CustomName:"Hol mich",CustomNameVisible:true,Item:{id:"minecraft:red_shulker_box",Count:1b,tag:{display:{Name:"Drop-Sensor:5",Lore:["Hebe den Gegenstand auf"] } } } },{id:"minecraft:item",Tags:["EtiDrSen:5Alle"],CustomName:"Hol mich",CustomNameVisible:true,Item:{id:"minecraft:red_shulker_box",Count:1b,tag:{display:{Name:"Drop-Sensor:5",Lore:["Hebe den Gegenstand auf"] } } } } ] }
execute @e[type=minecraft:falling_block,tag=EtiDrSen:5Alle] ~ ~ ~ /spreadplayers ~ ~ 2 10 false @e[type=minecraft:item,tag=EtiDrSen:5Alle]


tellraw @a[score_PZDrSen:5Aufheb_min=1] ["Drop-Sensor:5 ",{"text":"Du hast eine rote Shulkerkiste aufgehoben"} ]
clear @a[score_PZDrSen:5Aufheb_min=1] minecraft:red_shulker_box -1 1 {display:{Name:"Drop-Sensor:5"} }
scoreboard players reset @a[score_PZDrSen:5Aufheb_min=1] PZDrSen:5Aufheb


scoreboard objectives remove PZDrSen:5Aufheb
kill @e[type=minecraft:item,tag=EtiDrSen:5Alle]


Disambig color.svg
Grid Grasblock.png
Auch im Minecraft Wiki wird das Thema dieser Technik behandelt:
Drop